UDF > GUI > GuiAVI >

_GUICtrlAVI_Destroy

Supprime le contrôle

#include <GuiAVI.au3>
_GUICtrlAVI_Destroy ( ByRef $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne True, $hWnd est défini à 0.
Échec: Retourne False.

Remarque

Réservé à une utilisation exclusive aux contrôles AVI créés avec _GUICtrlAVI_Create().

En relation

_GUICtrlAVI_Create

Exemple

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $hGUI, $hAVI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"

    ; Crée une GUI
    $hGUI = GUICreate("(External) AVI Destroy", 300, 100)
    $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
    GUISetState(@SW_SHOW)

    ; Ouvre l'exemple AutoIt AVI
    _GUICtrlAVI_Open($hAVI, $sFile)

    ; Joue l'eexemple AutoIt AVI
    _GUICtrlAVI_Play($hAVI)

    Sleep(3000)

    ; Arrête le clip AVI après 3 secondes
    _GUICtrlAVI_Stop($hAVI)

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($hAVI)

    MsgBox($MB_SYSTEMMODAL, "Information", "Destroy AVI Control")
    _GUICtrlAVI_Destroy($hAVI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example