UDF > GUI > GuiAVI >

_GUICtrlAVI_Open

Ouvre un clip AVI et affiche sa première image dans un contrôle animation

#include <GuiAVI.au3>
_GUICtrlAVI_Open ( $hWnd, $sFileName )

Paramètres

$hWnd ID/handle du contrôle
$sFileName Nom complet (avec chemin) du fichier AVI

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Vous pouvez seulement ouvrir des clips AVI silencieux.

En relation

_GUICtrlAVI_Close, _GUICtrlAVI_OpenEx

Exemple

#include <GuiAVI.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $hGUI, $hAVI, $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\Examples\GUI\SampleAVI.avi"

    ; Crée une GUI
    $hGUI = GUICreate("(External) AVI Open", 300, 100)
    $hAVI = _GUICtrlAVI_Create($hGUI, "", -1, 10, 10)
    GUISetState(@SW_SHOW)

    ; Ouvre l'exemple AutoIt AVI
    _GUICtrlAVI_Open($hAVI, $sFile)

    ; Joue l'exemple AutoIt AVI
    _GUICtrlAVI_Play($hAVI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Ferme le clip AVI
    _GUICtrlAVI_Close($hAVI)

    GUIDelete()
EndFunc   ;==>Example