UDF > GDIPlus > GraphicsPath >

_GDIPlus_PathWiden

Remplace un tracé (GraphicsPath) par des courbes qui entourent la zone remplie lorsque ce tracé est dessiné avec un crayon spécifié. La fonction aplatit aussi le tracé.

#include <GDIPlus.au3>
_GDIPlus_PathWiden ( $hPath, $hPen [, $hMatrix = 0 [, $fFlatness = 0.25]] )

Paramètres

$hPath Handle de l'objet GraphicsPath
$hPen Handle du crayon. Le tracé est définit aussi large qu'il le serait s'il était dessiné avec ce crayon. Si 0, un crayon noir solide avec une largeur de 1 sera utilisé
$hMatrix [optionnel] Handle de l'objet Matrix qui représente une transformation à appliquer en même temps que l'élargissement. Si 0, aucune transformation n'est appliquée
$fFlatness [optionnel] Nombre décimal qui spécifie l'erreur maximale entre le tracé et son approximation aplatie.
Une planéité faible augmente le nombre de segments de droite dans l'approximation

Valeur de retour

Succès: Retourne True.
Échec: Retourne False et définit @error <> 0, @extended contient le code erreur ($GPID_ERR*).

En relation

_GDIPlus_PathFlatten, _GDIPlus_PathWarp, _GDIPlus_PathWindingModeOutline

Voir aussi

Consultez GdipWidenPath dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI = GUICreate("GDI+", 800, 400)
    GUISetState(@SW_SHOW)

    _GDIPlus_Startup()
    Local $hGraphics = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    _GDIPlus_GraphicsSetSmoothingMode($hGraphics, $GDIP_SMOOTHINGMODE_HIGHQUALITY)
    _GDIPlus_GraphicsClear($hGraphics, 0xFF000000)

    Local $hPath = _GDIPlus_PathCreate()
    Local $hFormat = _GDIPlus_StringFormatCreate()
    _GDIPlus_StringFormatSetAlign($hFormat, 1)
    Local $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    Local $tLayout = _GDIPlus_RectFCreate(0, 0, 800, 400)
    _GDIPlus_PathAddString($hPath, "AutoIt rulez!", $tLayout, $hFamily, 0, 160, $hFormat)

    Local $hPen_Widen = _GDIPlus_PenCreate(0, 8)
    _GDIPlus_PenSetLineJoin($hPen_Widen, $GDIP_PENSETLINEJOIN_ROUND)
    _GDIPlus_PathWiden($hPath, $hPen_Widen)

    Local $hBrush = _GDIPlus_BrushCreateSolid(0xFF8800AA)
    _GDIPlus_GraphicsFillPath($hGraphics, $hPath, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_PenDispose($hPen_Widen)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_PathDispose($hPath)
    _GDIPlus_GraphicsDispose($hGraphics)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example