UDF > GDIPlus > StringFormat >

_GDIPlus_StringFormatCreate

Crée un objet StringFormat

#include <GDIPlus.au3>
_GDIPlus_StringFormatCreate ( [$iFormat = 0 [, $iLangID = 0]] )

Paramètres

$iFormat [optionnel] Flags StringFormat. Peut être l'un ou plusieurs des éléments suivants:
    0x0001 - Indique que l'ordre de lecture est de droite à gauche
    0x0002 - Indique que les lignes individuelles de texte sont dessinées verticalement sur le dispositif d'affichage
    0x0004 - Indique que les parties de caractères sont autorisés à recouvrir le rectangle de disposition de la chaîne
    0x0020 - Indique que les caractères Unicode de contrôle de la mise en page sont affichées avec un caractère représentatif
    0x0400 - Indique qu'une autre police est utilisée pour les caractères qui ne sont pas pris en charge dans la police demandée
    0x0800 - Indique que l'espace à la fin de chaque ligne est inclus dans une mesure de chaîne (par défaut MeasureString exclut cet espace)
    0x1000 - Indique que la césure du texte à la ligne suivante est désactivé
    0x2000 - Indique que seules des lignes entières sont affichées dans le rectangle de mise en page
    0x4000 - Indique que les caractères recouvrant le rectangle de mise en page et le texte s'étendant à l'extérieur du rectangle de mise en page peuvent s'afficher
$iLangID [optionnel] La langue à utiliser

Valeur de retour

Succès: Retourne le handle de l'objet StringFormat.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

L'objet StringFormat contient les informations relatives à la mise en page du texte (telles que l'alignement, l'orientation et les taquets de tabulation), les manipulations d'affichage (telles que l'insertion de points de sélection et la substitution des formes nationales de chiffres).
Lorsque vous en avez terminé avec l'objet StringFormat, appelez _GDIPlus_StringFormatDispose() pour libérer les ressources.

En relation

_GDIPlus_StringFormatDispose, _GDIPlus_StringFormatSetAlign

Voir aussi

Consultez GdipCreateStringFormat dans la Librairie MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>

Example()

Func Example()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

    ; Crée une GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState(@SW_SHOW)

    ; Dessine une chaîne
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, "Hello world", $hFont, $tLayout, $hFormat, $hBrush)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Nettoie les ressources
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)

    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>Example