UDF > GDIPlus > SolidBrush >


_GDIPlus_BrushCreateSolid

Crée un pinceau d'une couleur unie

#include <GDIPlus.au3>
_GDIPlus_BrushCreateSolid ( [$iARGB = 0xFF000000] )

Paramètre

$iARGB [optionnel] Composantes de la couleur du pinceau: Alpha, Rouge, Vert et Bleu

Valeur de retour

Succès: Retourne le handle du nouvel objet Brush.
Échec: Retourne 0 et définit @error <> 0, @extended contient le code erreur GPSTATUS ($GPID_ERR*).

Remarque

Lorsque vous en avez terminé avec le pinceau, appelez _GDIPlus_BrushDispose() pour libérer les ressources.

En relation

_GDIPlus_BrushDispose

Voir aussi

Cherchez GdipCreateSolidFill dans la Library MSDN.

Exemple

#include <GDIPlus.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hBrush1, $hBrush2

    ; Crée une GUI
    GUICreate("GDI+", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Crée des pinceaux
    _GDIPlus_Startup()
    $hBrush1 = _GDIPlus_BrushCreateSolid()
    $hBrush2 = _GDIPlus_BrushClone($hBrush1)

    ; Affiche les informations sur les pinceaux
    MemoWrite("Brush 1 handle : 0x" & Hex($hBrush1))
    MemoWrite("Brush 1 type ..: " & _GDIPlus_BrushGetType($hBrush1))
    MemoWrite("Brush 2 handle : 0x" & Hex($hBrush2))
    MemoWrite("Brush 2 type ..: " & _GDIPlus_BrushGetType($hBrush2))

    ; Nettoie les ressources
    _GDIPlus_BrushDispose($hBrush2)
    _GDIPlus_BrushDispose($hBrush1)
    _GDIPlus_Shutdown()

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage = '')
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite