UDF > EventLog >

_EventLog__OpenBackup

Ouvre un handle pour un journal d'événement de sauvegarde

#include <EventLog.au3>
_EventLog__OpenBackup ( $sServerName, $sFileName )

Paramètres

$sServerName Le nom UNC du serveur sur lequel le journal d'événement sera ouvert.
Si vide, l'opération est effectuée sur l'ordinateur local.
$sFileName Le nom du fichier de sauvegarde

Valeur de retour

Succès: Retourne le handle du journal d'événement de sauvegarde.
Échec: Retourne 0.

Remarque

Si le nom du fichier de sauvegarde spécifie un serveur distant, $sServerName doit être vide.

En relation

_EventLog__Backup, _EventLog__Close

Exemple

#include <EventLog.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hEventLog

    ; Crée une GUI
    GUICreate("EventLog", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 300, 0)
    GUICtrlSetFont($g_idMemo, 9, $FW_NORMAL, $GUI_FONTNORMAL, "Courier New")
    GUISetState(@SW_SHOW)

    $hEventLog = _EventLog__Open("", "Application")
    _EventLog__Backup($hEventLog, "C:\EventLog.bak")
    _EventLog__Close($hEventLog)

    $hEventLog = _EventLog__OpenBackup("", "C:\EventLog.bak")
    MemoWrite("Log full ........: " & _EventLog__Full($hEventLog))
    MemoWrite("Log record count : " & _EventLog__Count($hEventLog))
    MemoWrite("Log oldest record: " & _EventLog__Oldest($hEventLog))
    _EventLog__Close($hEventLog)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite