UDF > EventLog >

_EventLog__Count

Récupère le nombre d'enregistrements contenus dans un journal d'événement

#include <EventLog.au3>
_EventLog__Count ( $hEventLog )

Paramètre

$hEventLog Le handle du journal d'événement

Valeur de retour

Succès: Retourne le nombre d'enregistrements contenus dans le journal d'événement.
Échec: Retourne -1

Remarque

Le plus ancien enregistrement contenu dans le journal d'événement n'est pas nécessairement l'enregistrement numéro 1.
Pour déterminer le numéro de l'enregistrement le plus ancien contenu dans un journal d'événement, utilisez la fonction _EventLog__Oldest()

En relation

_EventLog__Full, _EventLog__Oldest

Exemple

#include <EventLog.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hEventLog

    ; Crée une GUI
    GUICreate("EventLog", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 300, 0)
    GUICtrlSetFont($g_idMemo, 9, $FW_NORMAL, $GUI_FONTNORMAL, "Courier New")
    GUISetState(@SW_SHOW)

    $hEventLog = _EventLog__Open("", "Application")
    MemoWrite("Log full ........: " & _EventLog__Full($hEventLog))
    MemoWrite("Log record count : " & _EventLog__Count($hEventLog))
    MemoWrite("Log oldest record: " & _EventLog__Oldest($hEventLog))
    _EventLog__Close($hEventLog)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite