UDF > EventLog >

_EventLog__Open

Ouvre un handle de journal d'événement

#include <EventLog.au3>
_EventLog__Open ( $sServerName, $sSourceName )

Paramètres

$sServerName Le nom UNC du serveur sur lequel le journal d'événement sera ouvert. Si vide, l'opération est effectuée sur l'ordinateur local.
$sSourceName Le nom du journal

Valeur de retour

Succès: Retourne le handle du journal d'événement.
Échec: Retourne 0.

Remarque

Pour fermer le Handle du journal d'événement, utilisez la fonction _EventLog__Close().

En relation

_EventLog__Clear, _EventLog__Close, _EventLog__Read, _EventLog__Report

Exemple

#include <EventLog.au3>
#include <FontConstants.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hEventLog

    ; Crée une GUI
    GUICreate("EventLog", 400, 300)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 300, 0)
    GUICtrlSetFont($g_idMemo, 9, $FW_NORMAL, $GUI_FONTNORMAL, "Courier New")
    GUISetState(@SW_SHOW)

    $hEventLog = _EventLog__Open("", "Application")
    MemoWrite("Log full ........: " & _EventLog__Full($hEventLog))
    MemoWrite("Log record count : " & _EventLog__Count($hEventLog))
    MemoWrite("Log oldest record: " & _EventLog__Oldest($hEventLog))
    _EventLog__Close($hEventLog)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite