UDF > Clipboard >

_ClipBoard_SetViewer

Ajoute la fenêtre spécifiée à la chaîne des vues du presse-papiers

#include <Clipboard.au3>
_ClipBoard_SetViewer ( $hViewer )

Paramètre

$hViewer Handle de la fenêtre à ajouter à la chaîne du presse-papiers

Valeur de retour

Succès: Retourne le handle de la fenêtre suivante dans la chaîne des vues du presse-papiers
Échec: Retourne 0 si il n'y a pas de vue dans le presse-papier

Remarque

Les fenêtres qui font partie de la chaîne des vues du presse-papiers doivent traiter les messages $WM_CHANGECBCHAIN ​et $WM_DRAWCLIPBOARD.
Chaque fenêtre des vues du presse-papiers appelle la fonction _SendMessage() pour passer ces messages à la fenêtre suivante dans la chaîne des vues.
Une fenêtre de vue du presse-papiers doit finalement se retirer de la chaîne en appelant la fonction _ClipBoard_ChangeChain().

En relation

_ClipBoard_ChangeChain, _ClipBoard_GetViewer

Voir aussi

Consultez SetClipboardViewer dans la Librairie MSDN.

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Global $g_idMemo, $g_hNext = 0

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialise le visualiseur du presse-papiers
    $g_hNext = _ClipBoard_SetViewer($hGUI)

    GUIRegisterMsg($WM_CHANGECBCHAIN, "WM_CHANGECBCHAIN")
    GUIRegisterMsg($WM_DRAWCLIPBOARD, "WM_DRAWCLIPBOARD")

    MemoWrite("GUI handle ....: " & $hGUI)
    MemoWrite("Viewer handle .: " & _ClipBoard_GetViewer())

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Arrête le visualiseur du presse-papiers
    _ClipBoard_ChangeChain($hGUI, $g_hNext)
EndFunc   ;==>Example

; Ecrit un message dans Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Gestionnaire des messages $WM_CHANGECBCHAIN
Func WM_CHANGECBCHAIN($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Montre que le message a été reçu
    MemoWrite("***** $WM_CHANGECBCHAIN *****")

    ; Si la fenêtre suivante se ferme, répare la chaîne
    If $wParam = $g_hNext Then
        $g_hNext = $lParam
        ; Sinon passe le message au visualiseur suivant
    ElseIf $g_hNext <> 0 Then
        _SendMessage($g_hNext, $WM_CHANGECBCHAIN, $wParam, $lParam, 0, "hwnd", "hwnd")
    EndIf
EndFunc   ;==>WM_CHANGECBCHAIN

; Gestionnaire des messages $WM_DRAWCLIPBOARD
Func WM_DRAWCLIPBOARD($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Affiche un texte dans le presse-papiers
    MemoWrite(_ClipBoard_GetData())

    ; Passe le message au visualiseur suivant
    If $g_hNext <> 0 Then _SendMessage($g_hNext, $WM_DRAWCLIPBOARD, $wParam, $lParam)
EndFunc   ;==>WM_DRAWCLIPBOARD