UDF > Clipboard >

_ClipBoard_GetData

Récupère les données du presse-papiers dans un format spécifié

#include <Clipboard.au3>
_ClipBoard_GetData ( [$iFormat = 1] )

Paramètre

$iFormat [optionnel] Spécifie un format de presse-papiers:
$CF_TEXT - Format texte
$CF_BITMAP - Handle d'une image bitmap (HBITMAP)
$CF_METAFILEPICT - Handle d'un métafichier d'image (METAFILEPICT)
$CF_SYLK - Format Microsoft Symbolic Link (SYLK)
$CF_DIF - Format Data Interchange de Software Arts
$CF_TIFF - Format Tagged Image File
$CF_OEMTEXT - Format texte contenant des caractères dans le jeu de caractères OEM
$CF_DIB - Structure de BITMAPINFO suivie par les bits du bitmap
$CF_PALETTE - Handle d'une palette de couleurs
$CF_PENDATA - Données pour les extensions de crayon à Pen Computing
$CF_RIFF - Représente les données audio au format RIFF
$CF_WAVE - Représente les données audio au format WAVE
$CF_UNICODETEXT - Format texte Unicode
$CF_ENHMETAFILE - Handle d'un métafichier étendu (HENHMETAFILE)
$CF_HDROP - Handle d'un type HDROP qui identifie une liste de fichiers
$CF_LOCALE - Handle d'un identifiant de paramètres régionaux associés au texte du presse-papiers
$CF_DIBV5 - Structure BITMAPV5HEADER suivie par les couleurs du bitmap et des bits du bitmap
$CF_OWNERDISPLAY - Format d'affichage propriétaire
$CF_DSPTEXT - Format d'affichage de texte associé à un format privé
$CF_DSPBITMAP - Format d'affichage de bitmap associé à un format privé
$CF_DSPMETAFILEPICT - Format d'affichage de métafichier d'image associé à un format privé
$CF_DSPENHMETAFILE - Format d'affichage de métafichier amélioré associé à un format privé

Valeur de retour

Succès: Retourne du texte pour les formats texte ou des données binaires pour tous les autres formats
@extended est défini avec le nombre de caractères du texte, ou le nombre d'octets du Binary
Échec: Retourne 0

Remarque

Cette fonction effectue toutes les étapes nécessaire pour obtenir des données à partir du presse-papiers. Elle vérifie si le format de données est disponible, ouvre le presse-papiers, ferme le presse-papiers et retourne les données dans l'un des deux formats : format String pour les types de données $CF_TEXT, $CF_OEMTEXT, ou $CF_UNICODETEXT, ou format Binary pour tous les autres types.
Si vous avez besoin d'un degré de contrôle plus fin sur la récupération de données à partir du presse-papiers, vous pouvez utiliser la fonction _ClipBoard_GetDataEx().

En relation

_ClipBoard_GetDataEx, _ClipBoard_SetData, _ClipBoard_SetDataEx

Exemple

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $id_SetData, $id_GetData

    ; Crée une GUI
    GUICreate("Clipboard", 600, 450)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    $id_SetData = GUICtrlCreateButton("Set ClipBoard Data", 150, 410, 120, 30)
    $id_GetData = GUICtrlCreateButton("Get ClipBoard Data", 300, 410, 120, 30)
    GUISetState(@SW_SHOW)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $iMsg
    Do
        $iMsg = GUIGetMsg() 
        Switch $iMsg
            Case $id_SetData
                _ClipBoard_SetData("ClipBoard Library")
            Case $id_GetData
                MemoWrite(_ClipBoard_GetData())
        EndSwitch
    Until $iMsg = GUI_EVENT_CLOSE 
EndFunc   ;==>Example

; Ecrit un message dans memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite