Fonction _ClipBoard

La fenêtre, identifiée par $hNewNext, remplace la fenêtre $hRemove dans la chaîne.
La fonction _ClipBoard_SetViewer() envoie un message $WM_CHANGECBCHAIN à la première fenêtre de la chaîne des vues du presse-papiers.

#include <Clipboard.au3>
#include <GUIConstantsEx.au3>
#include <SendMessage.au3>
#include <WindowsConstants.au3>

Global $g_idMemo, $g_hNext = 0

Example()

Func Example()
    Local $hGUI

    ; Crée une GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Initialise les vues du presse-papiers
    $g_hNext = _ClipBoard_SetViewer($hGUI)

    GUIRegisterMsg($WM_CHANGECBCHAIN, "WM_CHANGECBCHAIN")
    GUIRegisterMsg($WM_DRAWCLIPBOARD, "WM_DRAWCLIPBOARD")

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; Arrête les vues du presse-papiers
    _ClipBoard_ChangeChain($hGUI, $g_hNext)
EndFunc   ;==>Example

; Ecrit un message dans memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; Gestionnaire des messages $WM_CHANGECBCHAIN
Func WM_CHANGECBCHAIN($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Montre que le message a été reçu
    MemoWrite("***** $WM_CHANGECBCHAIN *****")

    ; Si la fenêtre suivante se ferme, répare la chaîne
    If $wParam = $g_hNext Then
        $g_hNext = $lParam
        ; Sinon passe le message à l'autre vue
    ElseIf $g_hNext <> 0 Then
        _SendMessage($g_hNext, $WM_CHANGECBCHAIN, $wParam, $lParam, 0, "hwnd", "hwnd")
    EndIf
EndFunc   ;==>WM_CHANGECBCHAIN

; Gestionnaire des messages $WM_DRAWCLIPBOARD
Func WM_DRAWCLIPBOARD($hWnd, $iMsg, $wParam, $lParam)
    #forceref $hWnd, $iMsg
    ; Affiche du texte du presse-papiers
    MemoWrite(_ClipBoard_GetData())

    ; Passe le message à la vue suivante
    If $g_hNext <> 0 Then _SendMessage($g_hNext, $WM_DRAWCLIPBOARD, $wParam, $lParam)
EndFunc   ;==>WM_DRAWCLIPBOARD

UDF > Clipboard >

_ClipBoard_ChangeChain

Paramètres

Valeur de retour

Remarques

En relation

Voir aussi

Exemple

$hRemove	Handle de la fenêtre à retirer de la chaîne. La handle doit avoir été passé à la fonction _ClipBoard_SetViewer().
$hNewNext	Handle de la fenêtre qui suit la fenêtre $hRemove dans la chaîne des vues du presse-papiers. C'est le handle retourné par _ClipBoard_SetViewer() , à moins que la séquence ait été modifiée en réponse à un message $WM_CHANGECBCHAIN.