#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; Pour les constantes $TRAY_ICONSTATE_SHOW, $TRAY_ITEM_EXIT et $TRAY_ITEM_PAUSE.

Opt("TrayAutoPause", 0) ; Le script n'est pas mis en pause lors de la sélection de l'icône de la zone de notification.
Opt("TrayMenuMode", 2) ; Les items ne sont pas cochés lorsqu'ils sont sélectionnés.

Example()

Func Example()
    Local $idRandom = TrayCreateItem("Random:") ; Sélectionne cette option pour modifier le texte avec un nombre aléatoire.
    TrayCreateItem("") ; Crée une ligne de séparation.

    Local $idAbout = TrayCreateItem("About")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu dans la zone de notification.

    TrayItemSetText($TRAY_ITEM_EXIT, "Exit Program") ; Définit le texte de l'item par défaut 'Exit'.
    TrayItemSetText($TRAY_ITEM_PAUSE, "Pause Program") ; Définit le texte de l'item par défaut 'Pause'.
    Local $idMsg
    Do
        $idMsg = TrayGetMsg()
        Switch $idMsg
            Case $idAbout
                ; Affiche une boîte de message à propos de la version et
                ; du chemin d'installation de l'exécutable AutoIt.

                ; Recherche de droite à gauche l'antislash qui marque la fin du chemin
                Local $iASlash = StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1)
                ; Extrait le chemin seul, sans le nom, ni '\'
                Local $sPath = StringLeft(@AutoItExe, $iASlash - 1)

                MsgBox($MB_SYSTEMMODAL, "", "Exemple de menu dans la zone de notification." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Chemin d'installation: " & $sPath)

            Case $idRandom
                ; Définit le texte de l'item 'Random' avec un nombre aléatoire.
                TrayItemSetText($idRandom, "Random: " & Int(Random(1, 10, 1)))

        EndSwitch
    Until $idMsg = $TRAY_ITEM_EXIT
EndFunc   ;==>Example