#NoTrayIcon
#include <MsgBoxConstants.au3>
#include <StringConstants.au3>
#include <TrayConstants.au3> ; Pour la constante $TRAY_ICONSTATE_SHOW.

Opt("TrayMenuMode", 3) ; Les items de menu de la zone de notification, par défaut, ne seront pas affichés et les items ne seront pas cochés lorsqu'ils seront  sélectionnés. Ce sont les options 1 et 2 de TrayMenuMode.

Example()

Func Example()
    Local $idGetText = TrayCreateItem("Get 'About' Text")
    TrayCreateItem("") ; Crée une ligne de séparation.

    Local $idAbout = TrayCreateItem("About")
    TrayCreateItem("") ; Crée une ligne de séparation.

    Local $idExit = TrayCreateItem("Exit")

    TraySetState($TRAY_ICONSTATE_SHOW) ; Affiche le menu dans la zone de notification.

    Local $iASlash, $sPath, $iMsg = TrayGetMsg()
    While $iMsg <> $idExit
        Switch $iMsg
            Case $idAbout 
                ; Affiche une boîte de message à propos de la version et 
                ; du chemin d'installation de l'exécutable AutoIt.

                ; Recherche de droite à gauche l'antislash qui marque la fin du chemin
                $iASlash = StringInStr(@AutoItExe, "\", $STR_NOCASESENSEBASIC, -1)
                ; Extrait le chemin seul, sans le nom, ni '\'
                $sPath = StringLeft(@AutoItExe, $iASlash - 1)

                MsgBox($MB_SYSTEMMODAL, "", "Exemple de menu dans la zone de notification." & @CRLF & @CRLF & _
                        "Version: " & @AutoItVersion & @CRLF & _
                        "Chemin d'installation: " & $sPath) 

            Case $idGetText
                ; Affiche une boîte de message avec le texte de l'élément 'About'.
                MsgBox($MB_SYSTEMMODAL, "", "Le texte de l'élément 'About' est: " & TrayItemGetText($idAbout))

        EndSwitch

        $iMsg = TrayGetMsg()
    WEnd
EndFunc   ;==>Example