Functions > GUI > GUICtrlCreate >


GUICtrlCreateCheckbox

Crée un contrôle -Checkbox- présentant une liste de cases à cocher.

GUICtrlCreateCheckbox ( "text", left, top [, width [, height [, style = -1 [, exStyle = -1]]]] )

Paramètres

text Texte du contrôle Checkbox
left Coordonnée X du coin supérieur gauche du contrôle. Si égale à -1, alors X sera calculée en fonction de GUICoordMode.
top Coordonnée Y du coin supérieur gauche du contrôle. Si égale à -1, alors Y sera calculée en fonction de GUICoordMode.
width [optionnel] Largeur du contrôle (Ajuste automatiquement le texte par défaut dans la largeur).
height [optionnel] Hauteur du contrôle (Ajuste automatiquement le texte par défaut dans la largeur).
style [optionnel] Définit le style du contrôle. Consultez l'Annexe des styles de contrôle de GUI.
    Par défaut (-1) : $BS_AUTOCHECKBOX.
    Styles forcés : $WS_TABSTOP, et $BS_AUTOCHECKBOX si aucun styles chekkbox n'est défini.
exStyle [optionnel] Définit le style étendu du contrôle. Consultez la Table des styles étendus.

Valeur de retour

Succès: Retourne l'identifiant (ID du contrôle) du nouveau contrôle.
Échec: Retourne 0.

Remarques

Pour obtenir la valeur du contrôle, consultez GUICtrlRead.
Pour définir ou modifier des informations dans le contrôle, consultez GUICtrlUpdate....

Un contrôle de cases à cocher permet d'afficher une icône ou une image en utilisant le style $BS_ICON ou $BS_BITMAP. Utilisez GUICtrlSetImage pour spécifier l'image à utiliser.

Pour combiner les styles avec les styles par défaut, utilisez BitOR/a>($GUI_SS_DEFAULT_CHECKBOX, newstyle,...).

Pour utiliser les valeurs spécifiées ci-dessus, vous devez ajouter #include <ButtonConstants.au3> dans votre script.

Le redimensionnement par défaut est $GUI_DOCKHEIGHT.

En relation

GUICoordMode (Option), GUICtrlUpdate..., GUIGetMsg

Exemple


#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    ; Crée une GUI avec différents contrôles.
    Local $hGUI = GUICreate("Example", 300, 200)

    ; Crée un contrôle Checkbox.
    Local $idCheckbox = GUICtrlCreateCheckbox("Standard Checkbox", 10, 10, 185, 25)
    Local $idClose = GUICtrlCreateButton("Close", 210, 170, 85, 25)

    ; Affiche la GUI.
    GUISetState(@SW_SHOW, $hGUI)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Local $idMsg = GUIGetMsg()
    While ($idMsg <> $GUI_EVENT_CLOSE) And ($idMsg <> $idClose) 
        If $idMsg = $idCheckbox Then
            If _IsChecked($idCheckbox) Then
                MsgBox($MB_SYSTEMMODAL, "", "La checkbox est cochée.", 0, $hGUI)
            Else
                MsgBox($MB_SYSTEMMODAL, "", "La checkbox n'est pas cochée.", 0, $hGUI)
            EndIf
        EndIf
        $idMsg = GUIGetMsg()
    WEnd

    ; Supprime l'interface graphique précédente et tous ses contrôles.
    GUIDelete($hGUI)
EndFunc   ;==>Example

Func _IsChecked($idControlID)
    Return BitAND(GUICtrlRead($idControlID), $GUI_CHECKED) = $GUI_CHECKED
EndFunc   ;==>_IsChecked