UDF > NetShare >

_Net_Share_ConnectionEnum

Énumère toutes les connexions à une ressource partagée

#include <NetShare.au3>
_Net_Share_ConnectionEnum ( $sServer, $sQualifier )

Paramètres

$sServer Chaîne qui spécifie le nom DNS ou NetBIOS du serveur distant sur lequel la fonction s'exécutera.
Si ce paramètre est vide l'ordinateur local est utilisé.
$sQualifier Indique un nom de partage ou le nom de l'ordinateur qui vous intéresse.
S'il s'agit d'un nom de partage, alors toutes les connexions faites à ce nom de partage sont listés.
S'il s'agit d'un nom d'ordinateur, la fonction liste toutes les connexions faites à partir de l'ordinateur vers le serveur spécifié.

Valeur de retour

Succès: Retourne un tableau avec le format suivant:
    [0][0] - Nombre d'entrées dans le tableau
    [1][0] - Numéro d'identification de la connexion
    [1][1] - Type de connexion. Peut être une combinaison de:
        $STYPE_DISKTREE - Lecteur de disque
        $STYPE_PRINTQ - File d'attente d'impression
        $STYPE_DEVICE - Périphérique de communication
        $STYPE_IPC - IPC
        $STYPE_SPECIAL - Partage spécifique réservée aux IPC$ ou à l'administration à distance du serveur
        $STYPE_TEMPORARY - Partage temporaire
    [1][2] - Nombre de fichiers actuellement ouvert à la suite de la connexion
    [1][3] - Nombre d'utilisateurs sur la connexion
    [1][4] - Nombre de secondes écoulées depuis que la connexion a été établie
    [1][5] - Si le partage de la ressource serveur s'exécute avec la sécurité au niveau de l'utilisateur, ce membre décrit quel utilisateur a fait la connexion. Si le serveur est en cours d'exécution avec la sécurité au niveau partage, ce membre décrit quel ordinateur a fait la connexion.
    [1][6] - Indique le nom de partage de la ressource partagée du serveur ou le nom de l'ordinateur du client
Échec: Définit @error <> 0.

Remarque

Les droits d'Administrateur, d'Opérateur de serveur ou d'impression ou membre du groupe Power User sont nécessaires pour exécuter cette fonction

En relation

_Net_Share_FileEnum, _Net_Share_SessionEnum, _Net_Share_ShareEnum

Voir aussi

Consultez NetConnectionEnum dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <NetShare.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $sServer, $sShare, $aInfo

    ; Crée une GUI
    GUICreate("NetShare", 400, 300)

    ; Crée un contrôle Memo
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Obtient le serveur et les informations à partager
    $sServer = InputBox("NetWork Demo", "Entrez le nom du serveur:", "\\MyServer", "", 200, 130)
    If @error Then Exit
    $sShare = InputBox("NetWork Demo", "Entrez le nom de partage:", "MyShare", "", 200, 130)
    If @error Then Exit

    ; Énumère les connexions réseau
    $aInfo = _Net_Share_ConnectionEnum($sServer, $sShare)
    MemoWrite("Error ...................: " & @error)
    MemoWrite("Entries read ............: " & $aInfo[0][0])
    For $iI = 1 To $aInfo[0][0]
        MemoWrite("Connection ID ...........: " & $aInfo[$iI][0])
        MemoWrite("Connection type..........: " & _Net_Share_ResourceStr($aInfo[$iI][1]))
        MemoWrite("Number of files open ....: " & $aInfo[$iI][2])
        MemoWrite("Number of users .........: " & $aInfo[$iI][3])
        MemoWrite("Connection time .........: " & $aInfo[$iI][4])
        MemoWrite("Username ................: " & $aInfo[$iI][5])
        MemoWrite("Network name ............: " & $aInfo[$iI][6])
        MemoWrite()
    Next

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit un message dans le contrôle Memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite