UDF > GUI > GuiScrollBars >

_GUIScrollBars_GetScrollBarRGState

Obtient l'état d'un contrôle barre de défilement

#include <GuiScrollBars.au3>
_GUIScrollBars_GetScrollBarRGState ( $hWnd, $iObject )

Paramètres

$hWnd Le handle de la fenêtre
$iObject Spécifie l'objet barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $OBJID_CLIENT - Le paramètre $hWnd est le handle d'un contrôle barre de défilement.
    $OBJID_HSCROLL - La barre de défilement horizontale de la fenêtre $hWnd.
    $OBJID_VSCROLL - La barre de défilement verticale de la fenêtre $hWnd.

Valeur de retour

Succès: Retourne un tableau dans le format suivant:
    [0] - La barre de défilement elle-même.
    [1] - Le bouton de la flèche du haut ou de droite.
    [2] - La région Page Up ou Page Right.
    [3] - Le curseur de défilement (thumb).
    [4] - La région Page Down ou Page Left.
    [5] - Le bouton de la flèche du bas ou de gauche.
Échec: Définit @error <> 0.

En relation

_GUIScrollBars_GetScrollBarInfoEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI, $aRGState

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 2, 380, 360, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    $aRGState = _GUIScrollBars_GetScrollBarRGState($hGUI, $OBJID_HSCROLL)
    MemoWrite("Horizontal (Before)" & @CRLF & "--------------------------------------")
    For $x = 0 To 5
        MemoWrite("rgstate[" & $x & "]...: " & $aRGState[$x])
    Next

    MemoWrite(@CRLF & "Disable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_BOTH) & @CRLF)

    $aRGState = _GUIScrollBars_GetScrollBarRGState($hGUI, $OBJID_HSCROLL)
    MemoWrite("Horizontal (After)" & @CRLF & "--------------------------------------")
    For $x = 0 To 5
        MemoWrite("rgstate[" & $x & "]...: " & $aRGState[$x])
    Next

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite