UDF > GUI > GuiScrollBars >

_GUIScrollBars_EnableScrollBar

Active/Désactive les barres de défilement de la fenêtre spécifiée

#include <GuiScrollBars.au3>
_GUIScrollBars_EnableScrollBar ( $hWnd [, $iSBflags = $SB_BOTH [, $iArrows = $ESB_ENABLE_BOTH]] )

Paramètres

$hWnd Handle de la fenêtre
$iSBflags [optionnel] Spécifie le type de barre de défilement. Ce paramètre peut prendre l'une des valeurs suivantes:
    $SB_BOTH - Active ou désactive les flèches sur les barres de défilement horizontale et verticale associées à la fenêtre spécifiée.
    $SB_CTL - Indique que la barre de défilement est un contrôle ScrollBar. Le $hWnd doit être le handle du contrôle ScrollBar.
    $SB_HORZ - Active ou désactive les flèches sur la barre de défilement horizontale associée à la fenêtre spécifiée.
    $SB_VERT - Active ou désactive les flèches sur la barre de défilement verticale associée à la fenêtre spécifiée.
$iArrows [optionnel] Spécifie si les flèches de la barre de défilement sont activées ou désactivées et indique quelles flèches sont activées ou désactivées.
Ce paramètre peut prendre l'une des valeurs suivantes
    $ESB_DISABLE_BOTH - désactive les deux flèches sur une barre de défilement.
    $ESB_DISABLE_DOWN - Désactive la flèche vers le bas sur une barre de défilement verticale.
    $ESB_DISABLE_LEFT - Désactive la flèche gauche sur une barre de défilement horizontale.
    $ESB_DISABLE_LTUP - Désactive la flèche gauche sur une barre de défilement horizontale ou la flèche vers le haut d'une barre de défilement verticale.
    $ESB_DISABLE_RIGHT - Désactive la flèche droite sur une barre de défilement horizontale.
    $ESB_DISABLE_RTDN - Désactive la flèche droite sur une barre de défilement horizontale ou la flèche vers le bas d'une barre de défilement verticale.
    $ESB_DISABLE_UP - Désactive la flèche vers le haut sur une barre de défilement vertical.
    $ESB_ENABLE_BOTH - Active deux flèches sur une barre de défilement.

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUIScrollBars_ShowScrollBar

Voir aussi

Consultez EnableScrollBar dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiScrollBars.au3>
#include <WindowsConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $hGUI

    $hGUI = GUICreate("ScrollBar Example", 400, 400, -1, -1, BitOR($WS_MINIMIZEBOX, $WS_CAPTION, $WS_POPUP, $WS_SYSMENU, $WS_SIZEBOX))
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 380, 226, BitOR($WS_HSCROLL, $WS_VSCROLL))
    GUICtrlSetResizing($g_idMemo, $GUI_DOCKALL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetBkColor(0x88AABB)

    GUISetState(@SW_SHOW)

    _GUIScrollBars_Init($hGUI)

    MemoWrite("Disable down arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_DISABLE_DOWN))
    Sleep(3000)
    MemoWrite("Disable up arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_DISABLE_UP))
    Sleep(3000)
    MemoWrite("Enable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_VERT, $ESB_ENABLE_BOTH))
    Sleep(3000)
    MemoWrite("Disable left arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_LEFT))
    Sleep(3000)
    MemoWrite("Disable right arrow: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_DISABLE_RIGHT))
    Sleep(3000)
    MemoWrite("Enable both arrows: " & _GUIScrollBars_EnableScrollBar($hGUI, $SB_HORZ, $ESB_ENABLE_BOTH))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example

; Écrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite