UDF > GUI > GuiImageList >

_GUIImageList_DrawEx

Dessine un élément de la liste d'image dans le contexte de périphérique spécifié (méthode avancée)

#include <GuiImageList.au3>
_GUIImageList_DrawEx ( $hWnd, $iIndex, $hDC, $iX, $iY [, $iDX = 0 [, $iDY = 0 [, $iRGBBk = 0xFFFFFFFF [, $iRGBFg = 0xFFFFFFFF [, $iStyle = 0]]]]] )

Paramètres

$hWnd Handle de la liste d'images
$iIndex Index, de base de 0, de l'image à dessiner
$hDC Handle du contexte de périphérique de destination
$iX Coordonnée X où l'image sera dessinée
$iY Coordonnée Y où l'image sera dessinée
$iDX [optionnel] La largeur de la partie de l'image à dessiner par rapport au coin supérieur gauche de l'image.
Si $IDX et $Idy sont à zéro, la fonction dessine l'image entière. La fonction ne s'assure pas que les paramètres sont valides.
$iDY [optionnel] La hauteur de la partie de l'image à dessiner, par rapport au coin supérieur gauche de l'image.
Si $IDX et $Idy sont à zéro, la fonction dessine l'image entière. La fonction ne s'assure pas que les paramètres sont valides.
$iRGBBk [optionnel] La couleur de l'image d'arrière-plan. Ce paramètre peut être une valeur RVB définie par l'application ou l'une des valeurs suivantes:
    $CLR_NONE - Pas de couleur de fond. L'image est dessinée de manière transparente.
    $CLR_DEFAULT - La couleur de fond par défaut. L'image est dessinée en utilisant la couleur de fond de la liste d'images.
$iRGBFg [optionnel] La couleur de premier plan de l'image. Ce paramètre peut être une valeur RVB définie par l'application ou l'une des valeurs suivantes:
    $CLR_NONE - Pas de couleur de mélange. L'image est mélangée avec la couleur du contexte de périphérique de destination.
    $CLR_DEFAULT - La couleur de premier plan par défaut. L'image est dessinée en utilisant la couleur de surlignage du système comme couleur de premier plan.
$iStyle [optionnel] Style de dessin et superposition d'images:
    1 - Dessine l'image transparente en utilisant le masque, indépendamment de la couleur de fond
    2 - Dessine l'image, en mélangeant 25 pour cent de la couleur de surlignage du système
    4 - Dessine l'image, en mélangeant 50 pour cent de la couleur de surlignage du système
    8 - Dessine le masque

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUIImageList_Draw

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>
#include <WinAPIGdiDC.au3>

Example()

Func Example()
    Local $hImage, $hGUI, $hDC

    $hGUI = GUICreate("ImageList DrawEx", 400, 300)
    GUISetState(@SW_SHOW)

    ; Charge des images
    $hImage = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))

    ; Dessine les images
    $hDC = _WinAPI_GetDC($hGUI)
    _GUIImageList_DrawEx($hImage, 0, $hDC, 4, 4)
    _GUIImageList_DrawEx($hImage, 1, $hDC, 40, 4)
    _GUIImageList_DrawEx($hImage, 2, $hDC, 76, 4)

    _WinAPI_ReleaseDC($hGUI, $hDC)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example