UDF > GUI > GuiImageList >

_GUIImageList_Draw

Dessine un élément de la liste d'images dans le contexte de périphérique spécifié

#include <GuiImageList.au3>
_GUIImageList_Draw ( $hWnd, $iIndex, $hDC, $iX, $iY [, $iStyle = 0] )

Paramètres

$hWnd Handle de la liste d'images
$iIndex Index, de base de 0, de l'image à dessiner
$hDC Handle du contexte de périphérique de destination
$iX Coordonnée X où l'image sera dessinée
$iY Coordonnée Y où l'image sera dessonée
$iStyle [optionnel] Style de dessin et recouvrement d'images:
    1 - Dessine l'image transparente en utilisant le masque, indépendamment de la couleur de fond
    2 - Dessine l'image, mélange de 25 pour cent avec la couleur de surlignage du système
    4 - Dessine l'image, mélange de 50 pour cent avec la couleur de surlignage du système
    8 - Dessine le masque

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUIImageList_DrawEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <WinAPIGdi.au3>
#include <WinAPIGdiDC.au3>

Example()

Func Example()
    Local $hImage, $hGUI, $hDC

    $hGUI = GUICreate("ImageList Draw", 400, 300)
    GUISetState(@SW_SHOW)

    ; Charge des images
    $hImage = _GUIImageList_Create(32, 24)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 32, 24))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 32, 24))

    ; Dessine les images
    $hDC = _WinAPI_GetDC($hGUI)
    _GUIImageList_Draw($hImage, 0, $hDC, 4, 4)
    _GUIImageList_Draw($hImage, 1, $hDC, 40, 4)
    _GUIImageList_Draw($hImage, 2, $hDC, 76, 4)

    _WinAPI_ReleaseDC($hGUI, $hDC)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example