UDF > GUI > GuiTreeView >

_GUICtrlTreeView_SetState

Définit l'état du noeud spécifié

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetState ( $hWnd, $hItem [, $iState = 0 [, $bSetState = True]] )

Paramètres

$hWnd ID/handle du contrôle
$hItem Handle du noeud
$iState [optionnel] Le nouvel état du noeud, peut être l'un ou plusieurs des valeurs suivants:
    $TVIS_SELECTED - Noeud est sélectionné
    $TVIS_CUT - Noeud comme dans une opération couper-coller
    $TVIS_DROPHILITED - Noeud comme la cible d'un tirer-déposer
    $TVIS_BOLD - Noeud en gras
    $TVIS_EXPANDED - Noeud développé
    $TVIS_EXPANDEDONCE - La liste des noeuds enfants du noeud a été développée au moins une fois
    $TVIS_EXPANDPARTIAL - Noeud partiellement développé
$bSetState [optionnel] True si l'état du noeud doit être installé, False supprime l'état du noeud

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Les valeurs de l'état peuvent être conjuguées avec BitOR comme par exemple BITOR($TVIS_SELECTED, $TVIS_BOLD).

En relation

_GUICtrlTreeView_GetState

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $a_hItem[10], $hImage, $iImage, $iRand, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set State", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 9
        $iImage = Random(0, 5, 1)
        $a_hItem[$x] = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 5, 1)
            _GUICtrlTreeView_AddChild($idTreeView, $a_hItem[$x], StringFormat("[%02d] New Child", $y), $iImage, $iImage)
        Next
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    $iRand = Random(0, 9, 1)
    _GUICtrlTreeView_SetState($idTreeView, $a_hItem[$iRand], BitOr($TVIS_BOLD, $TVIS_EXPANDED)) ; mettre en gras et juste l'étendue"-\" pas vraiment élargi
    _GUICtrlTreeView_SetState($idTreeView, $a_hItem[$iRand], $TVIS_BOLD, False) ; état de réinitialisation juste Gras
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("State for Index %d: %s", $iRand, _GUICtrlTreeView_GetState($idTreeView, $a_hItem[$iRand])))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example