UDF > GUI > GuiTreeView >


_GUICtrlTreeView_SetNormalImageList

Définit la liste d'image normale pour le contrôle

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetNormalImageList ( $hWnd, $hImageList )

Paramètres

$hWnd ID/handle du contrôle
$hImageList Handle de la liste d'images. Si 0, toutes les images sont supprimées

Valeur de retour

Retourne le handle de la liste d'image précédente

En relation

_GUICtrlTreeView_GetNormalImageList

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Global Const $COLOR_Turquoise = 0x40e0d0
Global Const $COLOR_Crimson = 0xDC143C

Example()

Func Example()
    Local $hImage, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Normal ImageList", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    _GUICtrlTreeView_SetBkColor($idTreeView, $COLOR_Turquoise)
    _GUICtrlTreeView_SetTextColor($idTreeView, $COLOR_Crimson)
    _GUICtrlTreeView_SetLineColor($idTreeView, $COLOR_WHITE)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To 5
        _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Normal ImageList Handle: " & _GUICtrlTreeView_GetNormalImageList($idTreeView))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example