UDF > GUI > GuiTreeView >

_GUICtrlTreeView_SetIndent

Définit la largeur de l'indentation pour un contrôle TreeView et redessine le contrôle pour refléter la nouvelle largeur

#include <GuiTreeView.au3>
_GUICtrlTreeView_SetIndent ( $hWnd, $iIndent )

Paramètres

$hWnd ID/handle du contrôle
$iIndent Largeur, en pixels, de l'indentation.

Valeur de retour

Aucune.

Remarque

Si le paramètre $iIndent est inférieur à la largeur minimale définie par le système, la nouvelle largeur est réglée à ce minimum.

En relation

_GUICtrlTreeView_GetIndent

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hImage, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Set Indent", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 0 To _GUIImageList_GetImageCount($hImage) - 1
        _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x + 1), $x, $x)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    MsgBox($MB_SYSTEMMODAL, "Information", "Indent: " & _GUICtrlTreeView_GetIndent($idTreeView))

    _GUICtrlTreeView_SetIndent($idTreeView, 25)

    MsgBox($MB_SYSTEMMODAL, "Information", "Indent: " & _GUICtrlTreeView_GetIndent($idTreeView))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example