UDF > GUI > GuiTreeView >

_GUICtrlTreeView_AddChildFirst

Ajoute un nouveau noeud au début de la liste des enfants

#include <GuiTreeView.au3>
_GUICtrlTreeView_AddChildFirst ( $hWnd, $hParent, $sText [, $iImage = -1 [, $iSelImage = -1]] )

Paramètres

$hWnd ID/handle du contrôle
$hParent Noeud parent du noeud à ajouter
$sText Texte associé au noeud
$iImage [optionnel] Index, à partir de 0, de l'icône du noeud, dans la liste des images du contrôle
$iSelImage [optionnel] Index, à partir de 0, de l'icône du noeud, dans la liste des images du contrôle

Valeur de retour

Succès: Retourne le handle du nouveau noeud.
Échec: Retourne 0.

Remarque

Le noeud est ajouté en tant que premier enfant de $hParent. Les noeuds qui apparaissent après le noeud ajouté sont déplacés vers le bas.

En relation

_GUICtrlTreeView_AddChild

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTreeView.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hItem, $hImage, $iImage, $idTreeView
    Local $iStyle = BitOR($TVS_EDITLABELS, $TVS_HASBUTTONS, $TVS_HASLINES, $TVS_LINESATROOT, $TVS_DISABLEDRAGDROP, $TVS_SHOWSELALWAYS, $TVS_CHECKBOXES)

    GUICreate("TreeView Add Child First", 400, 300)

    $idTreeView = GUICtrlCreateTreeView(2, 2, 396, 268, $iStyle, $WS_EX_CLIENTEDGE)
    GUISetState(@SW_SHOW)

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, "shell32.dll", 146)
    _GUICtrlTreeView_SetNormalImageList($idTreeView, $hImage)

    _GUICtrlTreeView_BeginUpdate($idTreeView)
    For $x = 1 To Random(2, 10, 1)
        $iImage = Random(0, 5, 1)
        $hItem = _GUICtrlTreeView_Add($idTreeView, 0, StringFormat("[%02d] New Item", $x), $iImage, $iImage)
        For $y = 1 To Random(2, 10, 1)
            $iImage = Random(0, 4, 1)
            _GUICtrlTreeView_AddChild($idTreeView, $hItem, StringFormat("[%02d] New Child", $y), $iImage, $iImage)
        Next
        _GUICtrlTreeView_AddChildFirst($idTreeView, $hItem, "[00] First Child", 5, 5)
    Next
    _GUICtrlTreeView_EndUpdate($idTreeView)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example