UDF > GUI > GuiToolbar >

_GUICtrlToolbar_PressButton

Presse ou relâche un bouton spécifié

#include <GuiToolbar.au3>
_GUICtrlToolbar_PressButton ( $hWnd, $iCommandID [, $bPress = True] )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iCommandID ID de commande du bouton
$bPress [optionnel] Etat du bouton:
    True - Le bouton sera mis dans un état pressé
    False - Le bouton sera mis dans un état relâché

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Cette fonction ne déclenche pas l'événement click sur les boutons de style déroulant. Vous devez utiliser la fonction _GUICtrlToolbar_ClickButton()
fonctionner si vous voulez être sûr que l'événement clic du bouton soit déclenché, quel que soit le style de bouton.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar, $aStrings[4]
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    Switch _GUICtrlToolbar_GetBitmapFlags($hToolbar)
        Case 0
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_SMALL_COLOR)
        Case 2
            _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)
    EndSwitch

    ; Ajoute des chaînes
    $aStrings[0] = _GUICtrlToolbar_AddString($hToolbar, "&New Button")
    $aStrings[1] = _GUICtrlToolbar_AddString($hToolbar, "&Open Button")
    $aStrings[2] = _GUICtrlToolbar_AddString($hToolbar, "&Save Button")
    $aStrings[3] = _GUICtrlToolbar_AddString($hToolbar, "&Help Button")

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW, $aStrings[0])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN, $aStrings[1])
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE, $aStrings[2])
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP, $aStrings[3])

    ; Définit l'état du bouton Save
    MsgBox($MB_SYSTEMMODAL, "Information", "Save button pressed: " & _GUICtrlToolbar_IsButtonPressed($hToolbar, $e_idSave))
    _GUICtrlToolbar_PressButton($hToolbar, $e_idSave)
    MsgBox($MB_SYSTEMMODAL, "Information", "Save button pressed: " & _GUICtrlToolbar_IsButtonPressed($hToolbar, $e_idSave))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example