UDF > GUI > GuiToolbar >

_GUICtrlToolbar_InsertButton

Insère un bouton

#include <GuiToolbar.au3>
_GUICtrlToolbar_InsertButton ( $hWnd, $iIndex, $iID, $iImage [, $sText = "" [, $iStyle = 0 [, $iState = 4 [, $iParam = 0]]]] )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iIndex Index, de base 0, du bouton à gauche duquel insérer le nouveau bouton
$iID ID de la commande relative au bouton
$iImage Index, de base 0, de l'image
$sText [optionnel] Texte du bouton
$iStyle [optionnel] Style du bouton. Peut être une combinaison des éléments suivants:
    $BTNS_AUTOSIZE - Le contrôle ne doit pas attribuer la largeur standard au bouton
    $BTNS_BUTTON - Le bouton est standard
    $BTNS_CHECK - Bascule entre pressé et non pressé
    $BTNS_CHECKGROUP - Bouton qui reste enfoncé jusqu'à ce qu'un autre bouton soit pressé
    $BTNS_DROPDOWN - Crée un bouton de style déroulante qui permet d'afficher une liste
    $BTNS_GROUP - Bouton qui reste enfoncé jusqu'à ce qu'un autre bouton soit pressé
    $BTNS_NOPREFIX - Le texte du bouton n'aura pas un préfixe d'accélérateur
    $BTNS_SEP - Crée un séparateur
    $BTNS_SHOWTEXT - Indique que le texte du bouton doit être affiché
    $BTNS_WHOLEDROPDOWN - Indique que le bouton aura une flèche déroulante
$iState [optionnel] Etat du bouton. Peut être une combinaison des éléments suivants:
    $TBSTATE_CHECKED - Le bouton a été cliqué
    $TBSTATE_PRESSED - Le bouton est en train d'être cliqué
    $TBSTATE_ENABLED - Le bouton accepte l'entrée utilisateur
    $TBSTATE_HIDDEN - Le bouton n'est pas visible
    $TBSTATE_INDETERMINATE - Le bouton est grisé
    $TBSTATE_WRAP - Le bouton est suivie par un saut de ligne
    $TBSTATE_ELLIPSES - Le texte du bouton est coupée
    $TBSTATE_MARKED - Le bouton est marqué
$iParam [optionnel] Valeur définie par l'application

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Insère le nouveau bouton à gauche du bouton $iIndex

En relation

_GUICtrlToolbar_AddButton

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Ajoute des boutons
    _GUICtrlToolbar_InsertButton($hToolbar, 0, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_InsertButton($hToolbar, 1, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_InsertButton($hToolbar, 2, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_InsertButton($hToolbar, 4, $idHelp, $STD_HELP)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example