UDF > GUI > GuiToolbar >

_GUICtrlToolbar_DeleteButton

Supprime un bouton de la barre d'outils

#include <GuiToolbar.au3>
_GUICtrlToolbar_DeleteButton ( $hWnd, $iCommandID )

Paramètres

$hWnd Handle du contrôle barre d'outils
$iCommandID ID de commande du bouton

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlToolbar_AddButton

Exemple

#include <GUIConstantsEx.au3>
#include <GuiToolbar.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $hGUI, $hToolbar
    Local Enum $e_idNew = 1000, $e_idOpen, $e_idSave, $idHelp

    ; Crée une GUI
    $hGUI = GUICreate("Toolbar", 400, 300)
    $hToolbar = _GUICtrlToolbar_Create($hGUI)
    GUISetState(@SW_SHOW)

    ; Ajoute des bitmaps système standards
    _GUICtrlToolbar_AddBitmap($hToolbar, 1, -1, $IDB_STD_LARGE_COLOR)

    ; Ajoute des boutons
    _GUICtrlToolbar_AddButton($hToolbar, $e_idNew, $STD_FILENEW)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idOpen, $STD_FILEOPEN)
    _GUICtrlToolbar_AddButton($hToolbar, $e_idSave, $STD_FILESAVE)
    _GUICtrlToolbar_AddButtonSep($hToolbar)
    _GUICtrlToolbar_AddButton($hToolbar, $idHelp, $STD_HELP)

    ; Supprime le bouton Help
    MsgBox($MB_SYSTEMMODAL, "Information", "Suppression du bouton Help")
    _GUICtrlToolbar_DeleteButton($hToolbar, $idHelp)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>Example