UDF > GUI > GuiTab >

_GUICtrlTab_SetPadding

Définit la quantité d'espace autour de l'icône et de l'étiquette de chaque onglet

#include <GuiTab.au3>
_GUICtrlTab_SetPadding ( $hWnd, $iHorz, $iVert )

Paramètres

$hWnd ID/handle du contrôle Tab
$iHorz Quantité de marge horizontale, en pixels
$iVert Quantité de marge verticale, en pixels

Valeur de retour

Aucune.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $idTab

    ; Crée une GUI
    $hGUI = GUICreate("Tab Control Set Padding", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Crée des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($idTab, $hImage)

    ; Ajoute des onglets
    _GUICtrlTab_SetPadding($idTab, 20, 4)
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1", 0)
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2", 1)
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3", 2)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example