UDF > GUI > GuiTab >

_GUICtrlTab_SetItemImage

Définit l'image d'un onglet

#include <GuiTab.au3>
_GUICtrlTab_SetItemImage ( $hWnd, $iIndex, $iImage )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet
$iImage Index, de base 0, de l'image de l'onglet

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlTab_GetItemImage

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $idTab

    ; Crée une GUI
    $hGUI = GUICreate("Tab Control Set Item Image", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Crée des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($idTab, $hImage)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient/Définit l'image de l'onglet 2
    _GUICtrlTab_SetItemImage($idTab, 1, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Tab 2 image index: " & _GUICtrlTab_GetItemImage($idTab, 1))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example