UDF > GUI > GuiTab >

_GUICtrlTab_RemoveImage

Supprime une image de la liste d'images du contrôle

#include <GuiTab.au3>
_GUICtrlTab_RemoveImage ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'image à enlever

Valeur de retour

Aucune.

Remarque

Le contrôle à onglet met à jour chaque index d'image de chaque onglet, de sorte que chaque onglet reste associé avec la même image que précédemment.
Si un onglet utilisait l'image supprimée, l'onglet sera défini comme n'ayant aucune image.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiImageList.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>
#include <WinAPIGdi.au3>

Example()

Func Example()
    Local $hGUI, $hImage, $idTab

    ; Crée une GUI
    $hGUI = GUICreate("Tab Control Remove Image", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Crée des images
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 16, 16))
    _GUICtrlTab_SetImageList($idTab, $hImage)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1", 0)
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2", 1)
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3", 2)

    ; Retire la seconde image
    MsgBox($MB_SYSTEMMODAL, "Information", "Removing second image in list")
    _GUICtrlTab_RemoveImage($idTab, 1)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example