UDF > GUI > GuiTab >

_GUICtrlTab_GetItemRectEx

Obtient le rectangle englobant un onglet, dans une structure

#include <GuiTab.au3>
_GUICtrlTab_GetItemRectEx ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet

Valeur de retour

Retourne une structure $tagRECT qui reçoit le rectangle de l'onglet, dans les coordonnées de la fenêtre d'affichage.

En relation

$tagRECT, _GUICtrlTab_GetItemRect

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $tRECT, $sRect, $idTab

    ; Crée une GUI
    GUICreate("Tab Control Get Item RectEx", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient le rectangle de l'onglet 0
    $tRECT = _GUICtrlTab_GetItemRectEx($idTab, 0)
    $sRect = StringFormat("[%d, %d, %d, %d]", DllStructGetData($tRECT, "Left"), _
            DllStructGetData($tRECT, "Top"), _
            DllStructGetData($tRECT, "Right"), _
            DllStructGetData($tRECT, "Bottom"))
    MsgBox($MB_SYSTEMMODAL, "Information", "Display rectangle: " & $sRect)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example