UDF > GUI > GuiTab >

_GUICtrlTab_GetItemRect

Obtient le rectangle englobant un onglet, dans un tableau

#include <GuiTab.au3>
_GUICtrlTab_GetItemRect ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle Tab
$iIndex Index, de base 0, de l'onglet

Valeur de retour

Retourne un tableau avec le format suivant :
    [0] = Coordonnée X du coin supérieur gauche du rectangle
    [1] = Coordonnée Y du coin supérieur gauche du rectangle,
    [2] = Coordonnée X du coin inférieur droit du rectangle
    [3] = Coordonnée Y du coin inférieur droit du rectangle

En relation

_GUICtrlTab_GetItemRectEx

Exemple

#include <GUIConstantsEx.au3>
#include <GuiTab.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aRect, $sRect, $idTab

    ; Crée une GUI
    GUICreate("Tab Control Get Item Rect", 400, 300)
    $idTab = GUICtrlCreateTab(2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des onglets
    _GUICtrlTab_InsertItem($idTab, 0, "Tab 1")
    _GUICtrlTab_InsertItem($idTab, 1, "Tab 2")
    _GUICtrlTab_InsertItem($idTab, 2, "Tab 3")

    ; Obtient le rectangle de  tab 0
    $aRect = _GUICtrlTab_GetItemRect($idTab, 0)
    $sRect = StringFormat("[%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3])
    MsgBox($MB_SYSTEMMODAL, "Information", "Tab 0 rectangle: " & $sRect)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example