UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetNumberOfFirstVisibleLine

Obtient le numéro de la première ligne visible du contrôle

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetNumberOfFirstVisibleLine ( $hWnd )

Paramètre

$hWnd Handle du contrôle

Valeur de retour

Succès: Retourne le numéro de la ligne (à partir de 1).
Échec: Retourne 0 et définit @error <> 0.
@error: 101 - $hWnd n'est pas un handle

Remarque

La première ligne est numérotée 1.

Voir aussi

Consultez EM_GETFIRSTVISIBLELINE dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    For $i = 2 To 50
        _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Ligne " & $i)
    Next

    Report("La première ligne visible a le numéro " & _GUICtrlRichEdit_GetNumberOfFirstVisibleLine($hRichEdit))

    While GUIGetMsg() <> $GUI_EVENT_CLOSE
    WEnd

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report