UDF > GUI > GuiRichEdit >

_GUICtrlRichEdit_GetLineNumberFromCharPos

Obtient le numéro de la ligne sur laquelle se trouve une position inter- caractères donnée

#include <GuiRichEdit.au3>
_GUICtrlRichEdit_GetLineNumberFromCharPos ( $hWnd, $iCharPos )

Paramètres

$hWnd Handle du contrôle
$iCharPos La position inter-caractères

Valeur de retour

Succès: Retourne le numéro de ligne (à partir de 1).
Échec: Retourne 0 et définit @error <> 0.
@error: 101 - $hWnd n'est pas une handle
102 - $iCharPos n'est pas un nombre positif

Remarques

Un contrôle qui ne contient pas de texte a une ligne.
La première position inter-caractères d'un contrôle est.

La première ligne est la ligne 1.

Si $iCharPos est négatif ou plus élevé que le nombre de caractères du contrôle, retourne le nombre de lignes du contrôle.

Voir aussi

Consultez EM_EXLINEFROMCHAR dans la librairie MSDN.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiRichEdit.au3>
#include <WindowsConstants.au3>

Global $g_idLblMsg

Example()

Func Example()
    Local $hGui, $iMsg, $hRichEdit
    $hGui = GUICreate("Exemple (" & StringTrimRight(@ScriptName, 4) & ")", 320, 350, -1, -1)
    $hRichEdit = _GUICtrlRichEdit_Create($hGui, "Ceci est un test.", 10, 10, 300, 220, _
            BitOR($ES_MULTILINE, $WS_VSCROLL, $ES_AUTOVSCROLL))
    $g_idLblMsg = GUICtrlCreateLabel("", 10, 235, 300, 60)
    GUISetState(@SW_SHOW)

    _GUICtrlRichEdit_AppendText($hRichEdit, @CRLF & "Ceci est du texte ajouté")
    Report("La position inter-caractères 30 est sut la ligne " & _GUICtrlRichEdit_GetLineNumberFromCharPos($hRichEdit, 30))

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    _GUICtrlRichEdit_Destroy($hRichEdit) ; Nécessaire sauf si le script se bloque
    ; GUIDelete(); est OK aussi
EndFunc   ;==>Example

Func Report($sMsg)
    GUICtrlSetData($g_idLblMsg, $sMsg)
EndFunc   ;==>Report