UDF > GUI > GuiMenu >

_GUICtrlMenu_SetItemState

Définit l'état d'un élément de menu

#include <GuiMenu.au3>
_GUICtrlMenu_SetItemState ( $hMenu, $iItem, $iState [, $bState = True [, $bByPos = True]] )

Paramètres

$hMenu Handle du contrôle Menu
$iItem Identifiant ou position de l'élément de menu
$iState Propriété de l'élément dont il faut définir l'état​​:
    $MFS_CHECKED - L'élément est coché
    $MFS_DEFAULT - L'élément est l'élément par défaut
    $MFS_DISABLED - L'élément est désactivé
    $MFS_GRAYED - L'élément est grisé
    $MFS_HILITE - L'élément est mis en surbrillance
$bState [optionnel] Etat à définir pour l'élément:
    True  - État activé
    False - Etat désactivé
$bByPos [optionnel] Indicateur d'identifiant de menu:
    True  - $iItem est une position de base 0 de l'élément
    False - $iItem est un identifiant d'élément de menu

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlMenu_GetItemState, _GUICtrlMenu_GetItemStateEx

Exemple

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile

    ; Ouvre le Bloc-Notes
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Obtient l'état de l'élément Open
    _GUICtrlMenu_SetItemState($hFile, 1, $MFS_CHECKED)
    Writeln("Etat de l'élément Open: " & _GUICtrlMenu_GetItemStateEx($hFile, 1))
EndFunc   ;==>Example

; Ecrit une ligne de texte dans le Bloc-Notes
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln