UDF > GUI > GuiMenu >

_GUICtrlMenu_DrawMenuBar

Redessine la barre de menu de la fenêtre spécifiée

#include <GuiMenu.au3>
_GUICtrlMenu_DrawMenuBar ( $hWnd )

Paramètre

$hWnd Handle de la fenêtre dont la barre de menu doit être redessinée

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Si la barre de menu change après que Windows ait créé la fenêtre, cette fonction doit être appelée pour redessiner la barre de menu.

Voir aussi

Consultez DrawMenuBar dans la librairie MSDN.

Exemple

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hitem1, $hitem2

    ; Ouvre le Bloc-Notes
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)

    ; Crée un sous-menu
    $hitem1 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hitem1, 0, "Subitem &1", 0x1000)
    _GUICtrlMenu_InsertMenuItem($hitem1, 1, "Subitem &2", 0x1001)

    ; Crée un menu
    $hitem2 = _GUICtrlMenu_CreateMenu()
    _GUICtrlMenu_InsertMenuItem($hitem2, 0, "item &1", 0x2000, $hitem1)
    _GUICtrlMenu_InsertMenuItem($hitem2, 1, "item &2", 0x2001)
    _GUICtrlMenu_InsertMenuItem($hitem2, 2, "", 0)
    _GUICtrlMenu_InsertMenuItem($hitem2, 3, "item &3", 0x2002)
    _GUICtrlMenu_InsertMenuItem($hitem2, 4, "item &4", 0x2003)

    ; Insére le nouveau menu dans le Bloc-Notes
    _GUICtrlMenu_InsertMenuItem($hMain, 6, "&AutoIt", 0, $hitem2)
    _GUICtrlMenu_DrawMenuBar($hWnd)
EndFunc   ;==>Example