UDF > GUI > GuiMenu >

_GUICtrlMenu_GetItemInfo

Obtient des informations sur un élément de menu

#include <GuiMenu.au3>
_GUICtrlMenu_GetItemInfo ( $hMenu, $iItem [, $bByPos = True] )

Paramètres

$hMenu Handle du contrôle Menu
$iItem Identifiant ou position de l'élément de menu
$bByPos [optionnel] Indicateur d'identifiant de menu:
    True  - $iItem est une position de base 0 de l'élément
    False - $iItem est un identifiant d'élément de menu

Valeur de retour

Succès: Retourne une structure $tagMenuItemINFO.
Échec: Définit @error <> 0.

En relation

$tagMenuItemINFO, _GUICtrlMenu_SetItemInfo

Voir aussi

Consultez GetMenuItemInfo dans la librairie MSDN.

Exemple

#include <GuiMenu.au3>

Example()

Func Example()
    Local $hWnd, $hMain, $hFile, $tInfo

    ; Ouvre le Bloc-Notes
    Run("notepad.exe")
    WinWaitActive("[CLASS:Notepad]")
    $hWnd = WinGetHandle("[CLASS:Notepad]")
    $hMain = _GUICtrlMenu_GetMenu($hWnd)
    $hFile = _GUICtrlMenu_GetItemSubMenu($hMain, 0)

    ; Obtient/définit l'ID de la commande Open
    $tInfo = _GUICtrlMenu_GetItemInfo($hFile, 1)
    Writeln("ID commande Open: " & DllStructGetData($tInfo, "ID"))
    DllStructSetData($tInfo, "ID", 0)
    _GUICtrlMenu_SetItemInfo($hFile, 1, $tInfo)
    $tInfo = _GUICtrlMenu_GetItemInfo($hFile, 1)
    Writeln("ID commande Open: " & DllStructGetData($tInfo, "ID"))
EndFunc   ;==>Example

; Écrit une ligne de texte dans le Bloc-Notes
Func Writeln($sText)
    ControlSend("[CLASS:Notepad]", "", "Edit1", $sText & @CRLF)
EndFunc   ;==>Writeln