UDF > GUI > GuiListView >

_GUICtrlListView_SetSelectionMark

Définit la marque de sélection dans le contrôle

#include <GuiListView.au3>
_GUICtrlListView_SetSelectionMark ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index, de base 0, de la nouvelle marque de sélection. Si -1, la marque de sélection est supprimée.

Valeur de retour

Succès: Retourne la marque de sélection précédente.
Échec: Retourne -1 s'il n'y a pas de marque de sélection précédente.

Remarque

La marque de sélection est l'index de l'élément à partir duquel une sélection multiple commence.
Cette fonction n'affecte pas l'état de sélection de l'élément.

En relation

_GUICtrlListView_GetSelectionMark

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idListview

    GUICreate("ListView Set Selection Mark", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268, BitOR($LVS_SHOWSELALWAYS, $LVS_REPORT))
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)

    ; Ajoute des éléments
    _GUICtrlListView_AddItem($idListview, "Item 1")
    _GUICtrlListView_AddItem($idListview, "Item 2")
    _GUICtrlListView_AddItem($idListview, "Item 3")

    ; Sélectionne l'élément 1
    _GUICtrlListView_SetSelectionMark($idListview, 1)
    MsgBox($MB_SYSTEMMODAL, "Information", "Selected Mark: " & _GUICtrlListView_GetSelectionMark($idListview))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example