UDF > GUI > GuiListView >

_GUICtrlListView_JustifyColumn

Définit la justification d'une colonne d'un contrôle ListView

#include <GuiListView.au3>
_GUICtrlListView_JustifyColumn ( $hWnd, $iIndex [, $iAlign = -1] )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de la nouvelle colonne, de base 0
$iAlign [optionnel] Alignement de l'entête de colonne et du texte du sous-élément de la colonne :
    0 - Le texte est aligné à gauche
    1 - Le texte est aligné à droite
    2 - Le texte est centré

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

En relation

_GUICtrlListView_GetColumn, _GUICtrlListView_SetColumn

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $idListview

    GUICreate("ListView Justify Column", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Column 1", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 2", 100)
    _GUICtrlListView_AddColumn($idListview, "Column 3", 100)

    ; Modifie une colonne
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Column 1 Justification: " & $aInfo[0])
    _GUICtrlListView_JustifyColumn($idListview, 0, 2)
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Column 1 Justification: " & $aInfo[0])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example