UDF > GUI > GuiListView >

_GUICtrlListView_GetColumn

Obtient les attributs d'une colonne

#include <GuiListView.au3>
_GUICtrlListView_GetColumn ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index de la colonne, de base 0

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Alignement de l'en-tête de colonne et du texte du sous-élément dans la colonne:
        0 - Le texte est aligné à gauche
        1 - Le texte est aligné à droite
        2 - Le texte est centré
    [1] - True si l'élément affiche une image à partir d'une liste d'images
    [2] - True si le bitmap apparaît à droite du texte
    [3] - True si l'en-tête contient une image
    [4] - Largeur de la colonne, en pixels,
    [5] - Texte de l'en-tête de la colonne
    [6] - Index du sous-élément associé à la colonne
    [7] - Index, de base 0, d'une image de la liste d'images
    [8] - Numéro d'ordre de la colonne, de base 0

En relation

_GUICtrlListView_JustifyColumn, _GUICtrlListView_SetColumn

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aInfo, $idListview

    GUICreate("ListView Get Column", 400, 300)
    $idListview = GUICtrlCreateListView("col1|col2|col3", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($idListview, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    _GUICtrlListView_SetColumnWidth($idListview, 0, 100)
    GUISetState(@SW_SHOW)

    GUICtrlCreateListViewItem("index 0|data1|more1", $idListview)
    GUICtrlCreateListViewItem("index 1|data2|more2", $idListview)
    GUICtrlCreateListViewItem("index 2|data3|more3", $idListview)
    GUICtrlCreateListViewItem("index 3|data4|more4", $idListview)
    GUICtrlCreateListViewItem("index 4|data5|more5", $idListview)

    ; Modifie la colonne
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Column 1 Width: " & $aInfo[4])
    _GUICtrlListView_SetColumn($idListview, 0, "New Column 1", 150)
    $aInfo = _GUICtrlListView_GetColumn($idListview, 0)
    MsgBox($MB_SYSTEMMODAL, "Information", "Column 1 Width: " & $aInfo[4])

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example