UDF > GUI > GuiListView >

_GUICtrlListView_GetViewRect

Obtient le rectangle englobant tous les éléments du contrôle

#include <GuiListView.au3>
_GUICtrlListView_GetViewRect ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne un tableau avec le format suivant:
    [0] - Coordonnée X du coin supérieur gauche du rectangle
    [1] - Coordonnée Y du coin supérieur gauche du rectangle,
    [2] - Coordonnée X du coin inférieur droit du rectangle
    [3] - Coordonnée Y du coin inférieur droit du rectangle

Remarque

Le contrôle doit être en mode d'affichage Icônes ou Petites Icônes.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $aRect, $idListview

    GUICreate("ListView Get View Rect", 400, 300)
    $idListview = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState(@SW_SHOW)

    ; Ajoute des colonnes
    _GUICtrlListView_AddColumn($idListview, "Items", 100)

    ; Ajoute des éléments
    _GUICtrlListView_BeginUpdate($idListview)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($idListview, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($idListview)

    ; Définit le mode d'affichage
    _GUICtrlListView_SetView($idListview, 3)

    ; Obtient le rectangle de la vue
    $aRect = _GUICtrlListView_GetViewRect($idListview)
    MsgBox($MB_SYSTEMMODAL, "Information", StringFormat("View Tile: [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>Example