UDF > GUI > GuiListBox >

_GUICtrlListBox_GetCurSel

Obtient l'index de l'élément sélectionné

#include <GuiListBox.au3>
_GUICtrlListBox_GetCurSel ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne l'index de l'élément sélectionné, compté à partir de 0.
Échec: Retourne -1 s'il n'y a pas de sélection.

Remarque

Ne pas utiliser avec une ListBox à sélection multiple.

En relation

_GUICtrlListBox_SetCurSel

Exemple

#include <GUIConstantsEx.au3>
#include <GuiListBox.au3>
#include <WinAPIError.au3>

Example()

Func Example()
    Local $idListBox

    ; Crée une GUI
    GUICreate("List Box Get Cur Sel", 400, 296)
    $idListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des chaînes
    _GUICtrlListBox_BeginUpdate($idListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($idListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($idListBox)

    ; Sélectionne un élément
    _GUICtrlListBox_SetCurSel($idListBox, 4)

    ; Obtient l'élément sélectionné courant
    _WinAPI_ShowMsg("Current selection: " & _GUICtrlListBox_GetCurSel($idListBox))

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example