UDF > GUI > GuiEdit >

_GUICtrlEdit_FmtLines

Insère/Supprime des caractères de saut de ligne 'soft' dans un contrôle d'édition

#include <GuiEdit.au3>
_GUICtrlEdit_FmtLines ( $hWnd [, $bSoftBreak = False] )

Paramètres

$hWnd ID/handle du contrôle
$bSoftBreak [optionnel] Indique si des caractères de saut de ligne 'soft' doivent être insérés ou supprimés:
    True - Insère les caractères
    False - Les supprime

Valeur de retour

Retourne la même valeur que le paramètre $bSoftBreak.

Remarques

Un saut de ligne soft se compose de deux Carriage Return et d'un Line Feed et est inséré à la fin d'une ligne qui est coupée par césure.

Cette fonction ne concerne que le texte retourné par la fonction _GUICtrlEdit_GetText().

Elle n'a aucun effet sur l'affichage du texte dans le contrôle d'édition.

La fonction _GUICtrlEdit_FmtLines() n'affecte pas une ligne qui se termine par un saut de ligne hard.
Un saut de ligne hard se compose d'un Carriage Return et d'un Line Feed.

Exemple

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idEdit
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $sBefore, $sAfter

    ; Crée une GUI
    GUICreate("Edit FmtLines", 400, 300)
    $idEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    GUISetState(@SW_SHOW)

    ; Définit le texte
    _GUICtrlEdit_SetText($idEdit, FileRead($sFile, 500))

    ; Texte récupéré au format par défaut
    $sBefore = _GUICtrlEdit_GetText($idEdit)

    ; Insére des sauts de ligne 'soft'
    _GUICtrlEdit_FmtLines($idEdit, True)

    ; Texte avec des sauts de ligne 'soft'
    $sAfter = _GUICtrlEdit_GetText($idEdit)

    MsgBox($MB_SYSTEMMODAL, "Information", "Before:" & @CRLF & @CRLF & $sBefore & @CRLF & _
            '--------------------------------------------------------------'& @CRLF & _
            "After:" & @CRLF & @CRLF & $sAfter)

    ; Boucle jusqu'à ce que l'utilisateur quitte.
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example