UDF > GUI > GuiComboBox >

_GUICtrlComboBox_ShowDropDown

Affiche ou masque la liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_ShowDropDown ( $hWnd [, $bShow = False] )

Paramètres

$hWnd ID/handle du contrôle
$bShow [optionnel] Indique si la liste déroulante doit être montré ou caché:
    True - Montre la liste déroulante
    False - Masque la liste déroulante

Valeur de retour

Aucune.

Remarque

Cette fonction n'a aucun effet sur une ComboBox créée avec le style $CBS_SIMPLE.

En relation

_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_GetDroppedState

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Show Drop Down", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Obtient l'état déroulé/non déroulé
    MemoWrite("Dropped Down State......: " & _GUICtrlComboBox_GetDroppedState($idCombo))

    Sleep(500)

    ; Affiche la liste déroulante
    _GUICtrlComboBox_ShowDropDown($idCombo, True)

    Sleep(500)

    ; Obtient l'état déroulé/non déroulé
    MemoWrite("Dropped Down State......: " & _GUICtrlComboBox_GetDroppedState($idCombo))

    Sleep(500)

    ; Cache la liste déroulante
    _GUICtrlComboBox_ShowDropDown($idCombo)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite