UDF > GUI > GuiComboBox >

_GUICtrlComboBox_SetTopIndex

S'assure qu'un élément particulier est visible dans la liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetTopIndex ( $hWnd, $iIndex )

Paramètres

$hWnd ID/handle du contrôle
$iIndex Index, à partir de 0, de l'élément de liste

Valeur de retour

Succès: Retourne True.
Échec: Retourne False.

Remarque

Le système fait défiler le contenu de la liste déroulante afin que l'élément spécifié apparaîsse en haut de la liste ou de la zone de défilement maximale atteinte.

En relation

_GUICtrlComboBox_GetTopIndex

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Set Top Index", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Définit Top Index
    _GUICtrlComboBox_SetTopIndex($idCombo, 10)

    ; Obtient Top Index
    MsgBox($MB_SYSTEMMODAL, "Information", "Top Index:" & @TAB & _GUICtrlComboBox_GetTopIndex($idCombo))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example