UDF > GUI > GuiComboBox >

_GUICtrlComboBox_GetTopIndex

Obtient l'index, à partir de 0, du premier élément visible dans la partie zone de liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetTopIndex ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne l'index du premier élément visible dans la liste déroulante de la ComboBox.
Échec: Retourne -1.

En relation

_GUICtrlComboBox_SetTopIndex

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>
#include <WindowsConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Get Top Index", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Définit Top Index
    _GUICtrlComboBox_SetTopIndex($idCombo, 10)

    ; Obtient Top Index
    MsgBox($MB_SYSTEMMODAL, "Information", "Top Index:" & @TAB & _GUICtrlComboBox_GetTopIndex($idCombo))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example