UDF > GUI > GuiComboBox >

_GUICtrlComboBox_SetItemHeight

Définit la hauteur des éléments de liste ou de la zone de sélection d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetItemHeight ( $hWnd, $iHeight [, $iComponent = -1] )

Paramètres

$hWnd ID/handle du contrôle
$iHeight La hauteur, en pixels, du composant de la ComboBox identifié par $IComponent
$iComponent [optionnel] Utilisez les valeurs suivantes :
    –1 - Définit la hauteur de la zone de sélection
    0 - Règle la hauteur des éléments de la liste

Valeur de retour

Succès: Retourne 0.
Échec: Retourne -1 si la hauteur est invalide.

En relation

_GUICtrlComboBox_GetItemHeight

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Set Item Height", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Obtient hauteur d'élément (zone de sélection)
    MemoWrite("Item Height (selection field): " & _GUICtrlComboBox_GetItemHeight($idCombo))

    ; Obtient hauteur d'élément (éléments de la liste)
    MemoWrite("Item Height (list items): " & _GUICtrlComboBox_GetItemHeight($idCombo, 0))

    ; Définit Item Height (zone de sélection)
    _GUICtrlComboBox_SetItemHeight($idCombo, 18)

    ; Définit Item Height (zone de sélection)
    _GUICtrlComboBox_SetItemHeight($idCombo, 20, 0)

    ; Obtient Item Height (zone de sélection)
    MemoWrite("Item Height (selection field): " & _GUICtrlComboBox_GetItemHeight($idCombo))

    ; Obtient Item Height (élément de liste)
    MemoWrite("Item Height (list items): " & _GUICtrlComboBox_GetItemHeight($idCombo, 0))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite