UDF > GUI > GuiComboBox >

_GUICtrlComboBox_SetEditSel

Sélectionne les caractères dans le champ de saisie d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetEditSel ( $hWnd, $iStart, $iStop )

Paramètres

$hWnd ID/handle du contrôle
$iStart Position de départ
$iStop Position de fin

Valeur de retour

Succès: Retourne True.
Échec: Retourne False, si le message est envoyé à une ComboBox avec le style $CBS_DROPDOWN ou $CBS_DROPDOWNLIST.

Remarques

Les positions sont comptées à partir de 0. Le premier caractère du champ de saisie est en position zéro.
Si $iSTOP vaut -1, tout le texte de la position de départ jusqu'au dernier caractère du champ de saisie est sélectionné.

Le premier caractère après le dernier caractère sélectionné est en position de fin.

Par exemple, pour sélectionner les quatre premiers caractères du champ de saisie, utilisez une position de départ de 0 et une position de fin de 4.

En relation

_GUICtrlComboBox_GetEditSel, _GUICtrlComboBox_ReplaceEditSel

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aSel, $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Set Edit Sel", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Sélectionne un élément
    _GUICtrlComboBox_SetCurSel($idCombo, 2)

    ; Définit Edit Sel
    _GUICtrlComboBox_SetEditSel($idCombo, 0, 4)

    ; Obtient Edit Sel
    $aSel = _GUICtrlComboBox_GetEditSel($idCombo)
    MemoWrite(StringFormat("Edit Sel: %d - %d", $aSel[0], $aSel[1]))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle memo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite