UDF > GUI > GuiComboBox >

_GUICtrlComboBox_GetMinVisible

Obtient le nombre minimum d'éléments visibles dans la liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetMinVisible ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne le nombre minimal d'éléments visibles.
Échec: Retourne 0.

Remarques

Lorsque le nombre d'éléments dans la liste déroulante est supérieur au minimum, la ComboBox utilise une barre de défilement.

Cette fonction est ignorée si le contrôle ComboBox a le style $CBS_NOINTEGRALHEIGHT.

En relation

_GUICtrlComboBox_SetMinVisible

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Get Min Visible", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    ; Obtient Min Visible
    MsgBox($MB_SYSTEMMODAL, "Information", "Min Visible:" & @TAB & _GUICtrlComboBox_GetMinVisible($idCombo), 3)

    ; Affiche la liste déroulante
    _GUICtrlComboBox_ShowDropDown($idCombo, True)

    Sleep(500)

    ; Définit Min Visible
    _GUICtrlComboBox_SetMinVisible($idCombo, 50)

    ; Affiche la liste déroulante
    _GUICtrlComboBox_ShowDropDown($idCombo)

    Sleep(500)

    _GUICtrlComboBox_ShowDropDown($idCombo, True)

    Sleep(500)

    ; Obtient Min Visible
    MsgBox($MB_SYSTEMMODAL, "Information", "Min Visible:" & @TAB & _GUICtrlComboBox_GetMinVisible($idCombo), 3)

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example