UDF > GUI > GuiComboBox >

_GUICtrlComboBox_GetList

Obtient tous les éléments de la liste déroulante d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetList ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Retourne une chaîne délimitée de tous les éléments de la ComboBox.

Remarque

Par défaut le séparateur est "|", il peut être changé en utilisant Opt("GUIDataSeparatorChar","nouveau séparateur")

En relation

_GUICtrlComboBox_GetListArray

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

Global $g_idMemo

Example()

Func Example()
    Local $aList, $idCombo
    Opt("GUIDataSeparatorChar", ",") ; Définit le caractère séparateur que nous voulons utiliser

    ; Crée une GUI
    GUICreate("ComboBox Get List", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $g_idMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_AddDir($idCombo, "", $DDL_DRIVES, False)

    ; Obtient la  liste
    $aList = StringSplit(_GUICtrlComboBox_GetList($idCombo), ",")
    For $x = 1 To $aList[0]
        MemoWrite($aList[$x])
    Next

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle Mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite