UDF > GUI > GuiComboBox >

_GUICtrlComboBox_GetCueBanner

Obtient le texte de la bannière affichée dans la zone de saisie d'une ComboBox

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetCueBanner ( $hWnd )

Paramètre

$hWnd ID/handle du contrôle

Valeur de retour

Succès: Retourne le texte de la bannière.
Échec: Retourne une chaîne vide "".

Remarques

La bannière est le texte qui est affiché dans la zone de saisie d'une ComboBox quand il n'est pas sélectionné.

Windows Vista ou une version ultérieure.

En relation

_GUICtrlComboBox_SetCueBanner

Exemple

#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $g_idMemo
Example()

Func Example()
    Local $idCombo

    ; Crée une GUI
    GUICreate("ComboBox Get Count", 400, 296)
    $idCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    _GUICtrlComboBox_SetCueBanner($idCombo, "Select an Item")
    $g_idMemo = GUICtrlCreateEdit("", 10, 50, 376, 234, $WS_VSCROLL)
    GUICtrlSetFont($g_idMemo, 9, 400, 0, "Courier New")
    GUISetState(@SW_SHOW)

    ; Ajoute des fichiers
    _GUICtrlComboBox_BeginUpdate($idCombo)
    _GUICtrlComboBox_AddDir($idCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($idCombo)

    MemoWrite("Cue Banner: " & _GUICtrlComboBox_GetCueBanner($idCombo))

    ; Boucle jusqu'à ce que l'utilisateur quitte
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>Example

; Ecrit une ligne dans le contrôle mémo
Func MemoWrite($sMessage)
    GUICtrlSetData($g_idMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite